Hippo Content Export / Import

    // 1. Initialize (workflow) document manager and binary importing task using the default implementation.
    def documentManager = new WorkflowDocumentManagerImpl(session)
    def importTask = new DefaultBinaryImportTask(documentManager)
    // 1.1. Sets the logger to the import task, which is useful when running in groovy updater.
    importTask.setLogger(log)

    // 2. Starting import task, meaning the task starts the execution record bookkeeping.
    importTask.start()
          
          

    // 1. Find all the files which name end with ".json" by the regular expression in the source base VFS folder
    //    at the minimum depth level, 1, and the maximum depth level, 10.
    def sourceBaseFolder = VFS.getManager().resolveFile("file:///var/data/bindata")
    def files = importTask.findFilesByNamePattern(sourceBaseFolder, "^.+\\.json\$" , 1, 10)
          
          

    // 0. Iterate each JSON file from the collection.
    files.eachWithIndex { file, i ->

      // 1. Read ContentNode from a json file and find its primary type and node location from the meta property (jcr:path).
      def contentNode = importTask.readContentNodeFromJsonFile(file)
      def binaryPrimaryTypeName = contentNode.getPrimaryType()
      // determine the target binary handle node path to create or update binary content from the jcr:path meta property in ContentNode object.
      def binaryLocation = contentNode.getProperty("jcr:path").getValue()

      // 2. Record this import task unit and set the import soure file path as an attribute.
      //    The record instances will be collected and summarized when #logSummary() invoked later.
      def record = importTask.beginRecord("", binaryLocation)
      record.setAttribute("file", file.name.path)

      // 3. Mark this unit of import task is being processed before real processing below.
      record.setProcessed(true)

      // 4. Determine the target JCR folder path and binary content node name.
      def folderPathAndName = ContentPathUtils.splitToFolderPathAndName(binaryLocation)
      def binaryFolderPath = folderPathAndName[0]
      def binaryName = folderPathAndName[1]

      // 5. Choose proper binary node type, hippostd:foldertype and hippostd:gallerytype values for either gallery image or asset.
      //    These are internally used by Hippo Workflow. So let's carefully set those properties in any newly created binary folders.
      def binaryFolderPrimaryTypeName
      def binaryFolderFolderTypes
      def binaryFolderGalleryTypes

      if (binaryPrimaryTypeName == "hippogallery:imageset") {
        binaryFolderPrimaryTypeName = "hippogallery:stdImageGallery"
        binaryFolderFolderTypes = [ "new-image-folder" ] as String[]
        binaryFolderGalleryTypes = [ "hippogallery:imageset" ] as String[]
      } else if (binaryPrimaryTypeName == "hippogallery:exampleAssetSet") {
        binaryFolderPrimaryTypeName = "hippogallery:stdAssetGallery"
        binaryFolderFolderTypes = [ "new-file-folder" ] as String[]
        binaryFolderGalleryTypes = [ "hippogallery:exampleAssetSet" ] as String[]
      }

      // 6. Make sure that the binary target folder exists or get it created.
      def binaryFolderPath =
          importTask.createOrUpdateBinaryFolder(binaryFolderPath, binaryFolderPrimaryTypeName,
                                                binaryFolderFolderTypes, binaryFolderGalleryTypes)

      // 7. Create or update binary content from contentNode at the specific location with the name.
      def updatedBinaryLocation =
          importTask.createOrUpdateBinaryFromContentNode(contentNode, binaryPrimaryTypeName,
                                                         binaryFolderPath, binaryName)

      // 7.1. Extract text from binary if possible (e.g., application/pdf) and save hippo:text property underneath.
      HippoBinaryNodeUtils.extractTextFromBinariesAndSaveHippoTextsUnderHandlePath(documentManager.session, updatedBinaryLocation)

      // 8. Report that a unit of import process was done, so groovy updater engine can maintain its batch execution status properly.
      visitorContext.reportUpdated(binaryLocation)

      // 9. Mark this unit of import task successful.
      record.setSucceeded(true)

      // 10. End the current execution unit record.
      importTask.endRecord()
    }
          
          

    // 1. Stop the import task after processing, which means you stop execution recording.
    importTask.stop()

    // 2. Log the execution summary finally for administrator.
    importTask.logSummary()